Pricing as Code with Terraform

locals {
  # Prices are in cents.
  tiers = {
    starter = { title = "Starter", monthly = 1900, annual = 19000 }
    pro     = { title = "Pro", monthly = 4900, annual = 49000 }
    scale   = { title = "Scale", monthly = 14900, annual = 149000 }
  }
  tier_order = ["starter", "pro", "scale"]

  cycles = {
    monthly = { interval = "Month", label = "Monthly" }
    annual  = { interval = "Year", label = "Annual" }
  }

  # 3 tiers x 2 cycles = 6 plans, keyed "pro_annual" and so on.
  plans = {
    for pair in setproduct(keys(local.tiers), keys(local.cycles)) :
    "${pair[0]}_${pair[1]}" => {
      tier     = pair[0]
      cycle    = pair[1]
      title    = local.tiers[pair[0]].title
      monthly  = local.tiers[pair[0]].monthly
      price    = pair[1] == "monthly" ? local.tiers[pair[0]].monthly : local.tiers[pair[0]].annual
      interval = local.cycles[pair[1]].interval
      label    = local.cycles[pair[1]].label
    }
  }
}

resource "dodopayments_product" "plan" {
  for_each = local.plans

  name         = "${each.value.title} (${each.value.label})"
  tax_category = "saas"

  price = {
    type                         = "recurring_price"
    currency                     = "USD"
    price                        = each.value.price
    tax_inclusive                = false
    payment_frequency_count      = 1
    payment_frequency_interval   = each.value.interval
    subscription_period_count    = 20
    subscription_period_interval = "Year"
  }

  lifecycle {
    precondition {
      condition     = each.value.cycle == "monthly" || each.value.price <= floor(each.value.monthly * 12 * 0.9)
      error_message = "An annual plan must cost at least 10% less than 12 monthly payments."
    }
  }
}

resource "dodopayments_product_collection" "plans" {
  name = "Plans"

  groups = [
    for cycle in ["monthly", "annual"] : {
      group_name = local.cycles[cycle].label
      products = [
        for tier in local.tier_order : { product_id = dodopayments_product.plan["${tier}_${cycle}"].id }
      ]
    }
  ]

  effective_at_on_upgrade             = "immediately"
  proration_billing_mode_on_upgrade   = "prorated_immediately"
  effective_at_on_downgrade           = "next_billing_date"
  proration_billing_mode_on_downgrade = "do_not_bill"
}

resource "dodopayments_discount" "launch" {
  name   = "Launch: 20% off annual plans"
  code   = "LAUNCH20"
  type   = "percentage"
  amount = 2000 # basis points

  restricted_to       = [for tier in local.tier_order : dodopayments_product.plan["${tier}_annual"].id]
  expires_at          = "2027-06-30T23:59:59Z"
  subscription_cycles = 1
}

name: apply

on:
  push:
    branches: [main]

concurrency:
  group: apply-catalog
  cancel-in-progress: false

jobs:
  apply:
    runs-on: ubuntu-latest
    env:
      DODO_PAYMENTS_API_KEY: ${{ secrets.DODO_PAYMENTS_API_KEY }}
      TF_IN_AUTOMATION: "1"
    steps:
      - uses: actions/checkout@v6
      - uses: hashicorp/setup-terraform@v4
      - run: terraform init -input=false
      - run: terraform plan -input=false -out=tfplan
      - run: terraform apply -input=false tfplan

list "dodopayments_product" "all" {
  provider         = dodopayments
  include_resource = true
}